InvIoT - Menu Syntax

How to declare a menu array.

DESCRIPTION

The menu array is a type MENU.
MENU type is declare in the InvIoT_U1.h file.

With an array you can declares the choices of your menus and what function it will run.

Here is an example of a single row menu array:

MENU menuOptions[]={
{0," M e n u ",'t',0,0},
{0,"Print Hello",'f',helloWorld,0},
{0,"Turn Led Red ",'f',turnLedRed,0},
{0,"Turn Led Green ",'f',turnLedGreen,0},
{0,"Turn Led Off",'f',turnLedOff,0},
{255,"",' ',0},
};

SYNTAX

It looks complicated, but its not! After looking few examples it gets easy. But I still have to explain here all the syntax details for building menus.

Every item of the array contains:

<byte>,<String>,<char>,<Fuction name>,<byte>

<byte> Menu Group.

The root menu starts with 0.

255 declares the end of the menu array.

If there are submenus, this will be the sub menu group number.

<String> Text String

This is going to be printed on LCD.

<char> Menu Type

't' char declares Menu Title. This will be on top of the screen, not choosable, and is the Title of this menu group.

'f' char declares a Menu Function. This will be one of the choices you will have to choce from.

'm' char declares that is going to a Sub Menu. An arrow will be printed on LCD at the end of this line, to declare that there is a Sub Menu going to.

<Function Name> The function to run if you make that choice.

If this is for Menu Title ('t' char on previous field), enter 0.

If this is for Sub Menu choice ('m' char on previous field), enter 0.

If this is for Menu Function ('f' char on previous field), enter the name of the function to run when you make this choice.

<Byte> Return To.

If this is a Menu Title ('t' char) for a SubMenus, enter the Menu Group to return to when pressing the Cancel button.

If this is a single row menu (no submenus), enter 0 on this field so it will return to root menu.

If this is a submenu Title, enter the Menu Group you will like to go back to, when you press the Cancel button. Cancel button is on the right bottom corner of the InvIoT_U1 module.

If this is a Menu Function ('f' char), enter the Menu Group to return to, when exiting the function.

And finaly, if you exit a function and you want to return to the Screen Saver, and not to the menu, enter 255. This will be explain later in the ScreenSaver section

Example #1 - A Single Row Menu

#include <SPI.h>
#include <InvIoT_U1.h>

InvIoT_U1 lcd(A0,A1);
aIoTMenu menu;           //Create menu type aIoTMenu

void VOID(){}

MENU menuOptions[]={                         //All the items in array start with 0. First byte declares the Menu Group. Menu Group 0 is the root menu.

{0,"     M e n u   ",'t',VOID,0},              //Title of this Menu. Declare with the 't'. Printed on top of LCD.
 
 {0,"Print Hello    ",'f',helloWorld,0},     //run 'helloWorld' function. Its a 'f' type. Your 1st choice in the menu. Retrun to Root Menu (0) when exit 'helloWorld' function.
 {0,"Turn Led Red   ",'f',turnLedRed,0},     //run 'turnLedRed' function. Its a 'f' type. Your 2nd choice in the menu. Retrun to Root Menu (0) when exit 'turnLedRed' function.
 {0,"Turn Led Green ",'f',turnLedGreen,0},   //run 'turnLedGreen' function. Its a 'f' type. Your 2nd choice in the menu. Retrun to Root Menu (0) when exit 'turnLedGreen' function.
 {0,"Turn Led Off   ",'f',turnLedOff,0},     //run 'turnLedOff' function. Its a 'f' type. Your 2nd choice in the menu. Retrun to Root Menu (0) when exit 'turnLedOff' function.
 {255,"",' ',VOID,0},                             //End of Menu.
};

//********************* SETUP  and  LOOP   **************
void setup() {   
menu.menu=menuOptions;                   //Set menuOptions array to menu
menu.init('>',sizeof(menuOptions),lcd);  //Initialize menu. Character to use for cursor is '>'. Everything is send to lcd
}

void loop() {
 menu.runMenu();      // in the loop run menu all the time. It checks for rotary or button action.
}

//*********************  MENU FUNCTIONS    **************
void helloWorld(){
  lcd.clear();
  lcd.print("Hello Menu");
  delay(2000);
}

void turnLedRed(){
  lcd.led(1);
}

void turnLedGreen(){
  lcd.led(2);
}

void turnLedOff(){
  lcd.led(0);
}

Example #2 - A Menu with SubMenus

#include <SPI.h>
#include <InvIoT_U1.h>

InvIoT_U1 lcd(A0,A1);
aIoTMenu menu;           //Create menu type aIoTMenu

void VOID(){}

MENU menuOptions[]={                       //All the items in array start with 0. First byte declares the Menu Group. Menu Group 0 is the root menu.

{0,"Menu With SubMenus",'t',VOID,0},      // Title of this Menu. Declare with the 't'. Printed on top of LCD.
 {0,"Print Hello      ",'f',helloWorld,0}, // run 'helloWorld' function. Its a 'f' type. Your 1st choice in the menu. Retrun to Root Menu (0) when exit 'helloWorld' function.
 {0,"LED Functions    ",'m',VOID,1},       // THIS  WILL GO TO MENU #1. ITS A SUBMENU
 {0,"Buzzer Functions ",'m',VOID,2},       // THIS WILL GO TO MENU #2. ITS A SUBMENU.
 {0,"Hello AGAIN      ",'f',helloAgain,0}, // run 'helloAgain' function. Its a 'f' type.

//Lets build 'LED functions' sub Menu. All have Menu Group #1
 {1,"LED CONTROL",'t',VOID,0},            // Its the Title of menu group #1. when you are on this menu, hitting 'cancel button', will take you to Root Menu (0)
 {1,"Red   LED", 'f',turnLedRed,  1},     // It will run 'turnLedRed'. When exit stay on this submenu (1)
 {1,"Green LED", 'f',turnLedGreen,1},     // it will run 'turnLedGreen'. when exit stay on this submenu (1)
 {1,"LED Off  ", 'f',turnLedOff,1},       // It will run 'turnLedOff'. When exit for this function RETURN TO ROOT MENU (0)

//Now lets create 'Buzzer Functions' sub menu. All have Menu Group #2.
 {2, "Buzzer Test     ",'t',VOID,0},     // Its the Title of menu group #2. Go back to RootMenu(0) when hit the back button
 {2, "Just Buzz       ",'f',justBeep,2}, // when exit stay on 'Buzzer Function' subMenu (2)
 {2, "Rotary Click On ",'f',clickOn,0},  // when exit goto root menu
 {2, "Rotary Click Off",'f',clickOff,0}, // when exit goto root menu

{255,"",' ',VOID,0},                             //End of Menu.
};

//********************* SETUP  and  LOOP   **************
void setup() {   
menu.menu=menuOptions;                   //Set menuOptions array to menu
menu.init(')',sizeof(menuOptions),lcd);  //Initialize menu. Character to use for cursor is '>'. Everything is send to lcd
}

void loop() {
 menu.runMenu();      // in the loop run menu all the time. It checks for rotary or button action.
}

//*********************  MENU FUNCTIONS    **************
void helloWorld(){
  lcd.clear();
  lcd.print("Hello Menu");
  delay(2000);
}
void helloAgain(){
  lcd.clear();
  lcd.print("Hello AGAIN");
  delay(2000);
}

//functions for LED (1)
void turnLedRed(){
  lcd.led(1);
}

void turnLedGreen(){
  lcd.led(2);
}

void turnLedOff(){
  lcd.led(0);
}

//****functions for buzzer(2)
void justBeep() { //7
  lcd.setBuzzer(HIGH);
  delay(200);
  lcd.setBuzzer(LOW);
}
void clickOn() { //8
  lcd.rotaryClick = 5;
  lcd.buttonClick = 5;
}
void clickOff() { //9
  lcd.rotaryClick = 0;
  lcd.buttonClick = 0;
}